Module: Forms in Category Microsoft Access : Forms from Total Visual SourceBook

' Example of modForms
'
' To try this example, do the following:
' 1. Create a new form in your copy of Sample.mdb (in the Total Visual SourceBook sample directory).
'    Alternately, create a new form in the database of your choice, and import the following objects from Sample.mdb:
'       Table:    'Categories'
'       Form:     'Categories'
' 2. Make the Page and Form Header and Footer sections visible
' 3. Set the RecordSource property to the 'Categories'
' 4. Create the following command buttons
'       'cmdTest'
'       'cmdTestCombo'
'       'cmdSelect'
'       'cmdAdd'
'       'cmdFirst'
'       'cmdLast'
'       'cmdNext'
'       'cmdPrevious'
'       'cmdEnableDisable'
'       'cmdClose'
'       'cmdProps'
'       'cmdDelete'
'       'cmdSave'
'       'cmdUndo'
'       'cmdWait'
'       'cmdOpenCloseForms'
' 5. Create the following list boxes:
'       'lstForms'
'       'lstMacros'
'       'lstModules'
'       'lstReports'
' 6. Create a combo box 'cboTest'
' 7. Create a text box 'txtTest'
' 8. Add another form named 'frmProps' with 2 command buttons and 2 text boxes
' 8. Paste this code into the form's module

#If VBA7 Then
  Private Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal lngMilliSeconds As Long)
#Else
  Private Declare Sub Sleep Lib "kernel32" (ByVal lngMilliSeconds As Long)
#End If

Private Const mcstrFormName As String = "Categories"

Private Sub cmdOpenCloseForms_Click()
  If MsgBox("This will open all forms in design view, then close them all (including this form). " & vbCrLf & _
            "All forms will be saved on close." & vbCrLf & vbCrLf & "Continue?", vbYesNo) = vbYes Then
    FormOpenDesignAll acWindowNormal
    ' wait 2 seconds
    Sleep 2000
    FormCloseAll (True)
  End If
End Sub

Private Sub Form_Open(Cancel As Integer)

  cmdTest.Caption = "Test Access form functions"
  cmdTestCombo.Caption = "Test Combo"
  cmdSelect.Caption = "Select/Deselect"
  cmdAdd.Caption = "Add"
  cmdDelete.Caption = "Delete"
  cmdUndo.Caption = "Undo"
  cmdSave.Caption = "Save"
  cmdFirst.Caption = "First"
  cmdLast.Caption = "Last"
  cmdNext.Caption = "Next"
  cmdPrevious.Caption = "Prev"
  cmdEnableDisable.Caption = "Enable/Disable"
  cmdClose.Caption = "Close"
  cmdOpenCloseForms.Caption = "Open then Close Forms"
  cmdProps.Caption = "Form property"

  cmdWait.Caption = "Wait for " & mcstrFormName

  lstForms.RowSourceType = "ListFillForms"
  lstMacros.RowSourceType = "ListFillMacros"
  lstModules.RowSourceType = "ListFillModules"
  lstReports.RowSourceType = "ListFillReports"

  cboTest.RowSourceType = "Value List"
  cboTest.RowSource = "Red;Blue;Green;Yellow;Magenta"
  txtTest = "Hello Visual SourceBook Users"

  ' Example for Form_SetCommandButtons
  Form_SetCommandButtons Me, "Tahoma", 10, False

  ' Example for Form_SetFonts
  Form_SetFonts Me, "Tahoma", "10", True

  ' Example for Form_SetSectionColors
  Form_SetSectionColors Me, 15590879

End Sub

Private Sub cmdTest_Click()
  Dim astrControls() As String
  Dim astrForms() As String
  Dim intCount As Integer
  Dim intCounter As Integer
  Dim strControls As String
  Dim strForms As String
  Dim ctl As Control

  ' Example of FormsOpen
  If FormsOpen() Then
    Debug.Print "There are open forms"
  Else
    Debug.Print "There are no open forms"
  End If

  ' Example of FormControlsToArray
  intCount = FormControlsToArray(mcstrFormName, astrControls)
  Debug.Print "Form Controls:"
  For intCounter = 0 To intCount - 1
    Debug.Print intCounter & ": " & astrControls(intCounter)
  Next intCounter

  ' Example of FormControlsToString
  intCount = FormControlsToString(mcstrFormName, ";", strControls)
  Debug.Print "Controls: " & strControls

  ' Example of FormNamesToArray
  intCount = FormNamesToArray(astrForms)
  Debug.Print "Form names:"
  For intCounter = 0 To intCount - 1
    Debug.Print intCounter & ": " & astrForms(intCounter)
  Next intCounter

  ' Example of FormNamesToString
  intCount = FormNamesToString(strForms, ";")
  Debug.Print "Forms: " & strForms

  ' Example of FormMoveSizeInches
  FormMoveSizeInches Me.name, 1, 1, 5, 5

  ' Example of FormMoveSizetwips
  FormMoveSizeTwips Me.name, 1440, 1440, 7200, 7200

  ' Example of FormOnNewRecord
  Debug.Print "Form on new record: " & FormOnNewRecord(Me)

  ' Example of FormOpen
  FormOpen mcstrFormName, False

  ' Example of FormsOpenMinimized
  ' Uncomment the following line to test this function
  ' intCount = FormsOpenMinimized()

  ' Example of GetActiveForm
  Debug.Print "Active form: " & GetActiveForm()

  ' Example of GetControlType
  For Each ctl In Me.Controls
    Debug.Print "Control " & ctl.name & " is a " & GetControlType(ctl)
  Next ctl

  ' Example of IsFormOpen
  If IsFormOpen(mcstrFormName) Then
    Debug.Print mcstrFormName & " is open"
  Else
    Debug.Print mcstrFormName & " is not open"
  End If

  ' Example of CurrentFormView
  Debug.Print "Current form view for " & mcstrFormName & " is " & CurrentFormView(Forms(mcstrFormName))

  ' Reopen the form in Normal mode.
  FormOpenReplace mcstrFormName, acNormal

  ' Example form for IsFormOpenInMode
  If IsFormOpenInMode(mcstrFormName, acNormal) Then
    Debug.Print mcstrFormName & " is open in normal mode"
  Else
    Debug.Print mcstrFormName & " is not open in normal mode"
  End If

  ' Reopen the form in Datasheet view
  FormOpenReplace mcstrFormName, acFormDS

  ' Example of IsFormOpenInDatasheetView
  If IsFormOpenInDatasheetView(mcstrFormName) Then
    Debug.Print mcstrFormName & " is open in DatasheetView"
  Else
    Debug.Print mcstrFormName & " is not open in DatasheetView"
  End If

  ' Reopen the form in Datasheet view
  FormOpenReplace mcstrFormName, acNormal

  ' Example of IsFormOpenInFormView
  If IsFormOpenInFormView(mcstrFormName) Then
    Debug.Print mcstrFormName & " is open in FormView"
  Else
    Debug.Print mcstrFormName & " is not open in FormView"
  End If

  ' Example of IsFormOpenInLayoutView
  If IsFormOpenInLayoutView(mcstrFormName) Then
    Debug.Print mcstrFormName & " is open in LayoutView"
  Else
    Debug.Print mcstrFormName & " is not open in LayoutView"
  End If

  ' Example of IsFormOpenInDesignView
  If IsFormOpenInDesignView(mcstrFormName) Then
    Debug.Print mcstrFormName & " is open in DesignView"
  Else
    Debug.Print mcstrFormName & " is not open in DesignView"
  End If

  ' Example of IsSubForm
  If IsSubForm(Me) Then
    Debug.Print Me.name & " is a subform"
  Else
    Debug.Print Me.name & " is a subform"
  End If

  ' Example of Form_SetSectionColorsIndividually
  Form_SetSectionColorsIndividually Me, vbWhite, vbGreen, vbBlue, vbRed, vbYellow

End Sub

Private Sub cmdSelect_Click()
  ' Example of DeSelectControl, SelectControl

  Static fSelected As Boolean

  If fSelected Then
    DeSelectControl Me.txtTest
  Else
    SelectControl Me.txtTest, False
  End If

  fSelected = Not fSelected

End Sub

Private Sub cmdTestCombo_Click()
  ' Example of ComboBoxOpen
  ComboBoxOpen cboTest

  ' Example of ComboSetFirst
  ComboSetFirst cboTest

End Sub

Private Sub cmdEnableDisable_Click()
  ' Example of EnableDisableControls

  Static fEnable As Boolean

  EnableDisableControls Me, 0, fEnable
  fEnable = Not fEnable

  ' wait 2 seconds
  Sleep 2000

  EnableDisableControls Me, 0, fEnable
  fEnable = Not fEnable

End Sub

Private Sub cmdAdd_Click()
  ' Example of FormAddRecord

  FormAddRecord Me

End Sub

Private Sub cmdFirst_Click()
  ' Example of FormMoveFirst

  FormMoveFirst Me

End Sub

Private Sub cmdLast_Click()
  ' Example of FormMoveLast

  FormMoveLast Me

End Sub

Private Sub cmdNext_Click()
  ' Example of FormMoveNext

  FormMoveNext Me

End Sub

Private Sub cmdPrevious_Click()
  ' Example of FormMovePrevious

  FormMovePrevious Me

End Sub

Private Sub cmdClose_Click()
  ' Example of FormClose

  FormClose Me.name, True

End Sub

Private Sub cmdProps_Click()
  Dim intCount As Integer

  ' Example of FormControlPropertiesChange
  intCount = FormControlPropertiesChange(mcstrFormName, "ControlTipText", "Tip changed: " & Now, True)

  ' Example of FormPropertyChange
  If FormPropertyChange(mcstrFormName, "Caption", "New caption: " & Now, True) Then
    Debug.Print "Form caption changed."
  Else
    Debug.Print "Form caption could not be changed."
  End If

  DoCmd.OpenForm mcstrFormName, acNormal, , , , acDialog

End Sub

Private Sub cmdDelete_Click()
  ' Example of FormDeleteRecord

  If MsgBox("Are you sure you want to delete this record? It cannot be recovered once deleted.", vbYesNo) = vbYes Then
    FormDeleteRecord Me, True
  End If

End Sub

Private Sub cmdSave_Click()
  ' Example of FormSaveRecord
  FormSaveRecord Me
End Sub

Private Sub cmdUndo_Click()
  ' Example of FormUndoRecord
  FormUndoRecord Me

End Sub

Private Sub cmdWait_Click()
  ' Example of WaitUntilFormCloses
  MsgBox "before"
  FormOpen mcstrFormName, True
  WaitUntilFormClose mcstrFormName
  MsgBox "after"
End Sub

The source code in Total Visual Sourcebook includes modules and classes for Microsoft Access, Visual Basic 6 (VB6), and Visual Basic for Applications (VBA) developers. Easily add this professionally written, tested, and documented royalty-free code into your applications to simplify your application development efforts.

Total Visual SourceBook is written for the needs of a developer using a source code library covering the many challenges you face. Countless developers over the years have told us they learned some or much of their development skills and tricks from our code. You can too!

Additional Resources

• List of All Modules in Total Visual SourceBook
• List of All Code Categories in Total Visual SourceBook
• Sample Module Code from Total Visual SourceBook (Example of Date, Time and Age Calculations)