Class: MRU in Category Microsoft Visual Basic 6 : Menus from Total Visual SourceBook

' Example of the CMRU class
'
' To try this example, do the following:
' 1. Create a new form
' 2. Create the menu structure consisting of a top-level menu called 'mnuFile'.
' 3. Underneath this menu, create menu items called 'mnuFileOpen' and 'mnuFileSave'
' 4. Following mnuFileSave add a menu control array called 'mnuFileMRU' with 5 items, indexes 0 through 4.
'    The caption for the first mnuFileMRU item should be set to "-", which indicates that it is the divider item.
' 5. The complete menu structure should look something like this in the VBA/VB6 Tools, Menu Editor Dialog:
'
'    Caption         Menu Control Name
'    -----------------------------------
'    &File           mnuFile
'    ....&Open       mnuFileOpen
'    ....&Save       mnuFileSave
'    ....-           mnuFileMRU(0)
'    ....            mnuFileMRU(1)
'    ....            mnuFileMRU(2)
'    ....            mnuFileMRU(3)
'    ....            mnuFileMRU(4)
'
' 6. Add a FileOpen common file dialog control to the form, and name it "CommonDialog1"
' 7. Paste all the code from this example to the new form's module
' 8. Run the form. Try opening and saving files with the File Open and File Save menu,
'    and watching what happens to the Most Recently Used items on the File Menu.

' Declarations section code
Private mMRU As CMRU

Private Sub Form_Load()
  Set mMRU = New CMRU

  With mMRU
    .RootKey = mrrkHKeyLocalMachine
    .RegistryPath = "SOFTWARE\FMS\TestMRU"
    .SubKey = "MRU Entries"
    .Prefix = "MRU"
    .TagPrefix = "MRUTag"

    ' Assign the actual form's menu items to the corresponding properties of the CMRU object
    Set .MenuItem(0) = mnuFileMRU(0)
    Set .MenuItem(1) = mnuFileMRU(1)
    Set .MenuItem(2) = mnuFileMRU(2)
    Set .MenuItem(3) = mnuFileMRU(3)
    Set .MenuItem(4) = mnuFileMRU(4)

    ' Get the most recently saved list of files and update the menus
    .GetMRUList

  End With

End Sub

Private Sub mnuFileMRU_Click(Index As Integer)
  Dim strFile As String
  Dim strTag As String

  ' display the value stored in the caption and tag of the menu item
  strFile = mid$(mnuFileMRU(Index).Caption, 5)
  strTag = mnuFileMRU(Index).Tag

  MsgBox "Caption: " & strFile & vbCrLf & "Tag: " & strTag

  ' Move the selected menu item to the top of the list
  mMRU.SetMRUList strFile, strTag

End Sub

Private Sub mnuFileOpen_Click()
  ' Simulate an application opening a file, and updating the MRU list
  With CommonDialog1
    .DialogTitle = "Load File"
    .ShowOpen
    If .FileName <> "" Then
  ' Add the new file to the top of the list if it does not already exist.
  ' Otherwise, move the file from its current position to the top of the list.
  ' Store the length of the file in the .tag property of the menu item
      mMRU.SetMRUList .FileName, "File length: " & FileLen(.FileName)

    End If

  End With

End Sub

Private Sub mnuFileSave_Click()
  ' Simulate an application saving a new file, and updating the MRU list
  With CommonDialog1
    .DialogTitle = "Save File"
    .ShowOpen
    If .FileName <> "" Then
      mMRU.SetMRUList .FileName, "File length: " & FileLen(.FileName)
    End If

  End With

End Sub

The source code in Total Visual Sourcebook includes modules and classes for Microsoft Access, Visual Basic 6 (VB6), and Visual Basic for Applications (VBA) developers. Easily add this professionally written, tested, and documented royalty-free code into your applications to simplify your application development efforts.

Total Visual SourceBook is written for the needs of a developer using a source code library covering the many challenges you face. Countless developers over the years have told us they learned some or much of their development skills and tricks from our code. You can too!

Additional Resources

• List of All Modules in Total Visual SourceBook
• List of All Code Categories in Total Visual SourceBook
• Sample Module Code from Total Visual SourceBook (Example of Date, Time and Age Calculations)