Class: AccessAutomation in Category Microsoft Access : Automation from Total Visual SourceBook

' Example of CAccessAutomation
'
' To use this example, create a new module and paste this code into it.
' Then run the procedure by putting the cursor in the procedure and pressing:
'    F5 to run it, or
'    F8 to step through it line-by-line (see the Debug menu for more options)

Private Sub Example_CAccessAutomation()
  ' Comments: Examples of using the CAccessAutomation class to launch and run a Microsoft Access database using VBA and VB6

  Const cstrSamplePath As String = "C:\Total Visual SourceBook 2013\Samples\"
  Const cstrSampleDB As String = cstrSamplePath & "SAMPLE.MDB"
  Const cstrReportPDF As String = cstrSamplePath & "Invoices.PDF"
  Const cstrDuplicate As String = "Copy of Customers"
  Const cstrReport As String = "rptInvoice"
  Const cfVisible As Boolean = True

  ' Limit to the first 30 orders. Without it, there'd be 830 orders.
  Const cstrReportWhere As String = "[OrderID] <= 10277"

  Dim clsAccess As CAccessAutomation
  Dim fOK As Boolean
  Dim accApp As Access.Application
  Dim strSQL As String

  ' Initialize the variable to the automation class
  Set clsAccess = New CAccessAutomation

  With clsAccess
    If .StartAccess(cfVisible) Then
      ' Open the database
      If .OpenDatabase(cstrSampleDB, False) Then

        ' Use the Access object to invoke any Access method or property
        Set accApp = .AppAccess
        Debug.Print "Access Version " & accApp.Version
        Set accApp = Nothing

        ' Use the properties of the class
        Debug.Print "Access Path: " & .AccessPath
        Debug.Print "Access Version: " & .AccessVersion
        Debug.Print "Workgroup Path: " & .WorkgroupPath

        .Visible = False
        Debug.Print "Database set to invisible"

        fOK = .OpenForm("frmDepartment")
        Debug.Print "Form opened " & fOK

        ' Show Access again
        .Visible = True

        ' =====================================
        ' Previewing and printing a report

        ' Create a PDF file from the report. The report should not be in preview mode when this is called. A WHERE clause is used to limit the number of invoices.
        ' The PDF file is opened when it's created.
        .ReportOutputPDF cstrReport, cstrReportPDF, True, , cstrReportWhere

        fOK = .OpenReport(cstrReport, acViewPreview)
        Debug.Print "Report previewed " & fOK

        If MsgBox("Do you want to print one page of the sample report?", vbYesNo) = vbYes Then
          ' Print page 3
          fOK = .ReportPrintPages(cstrReport, 3, 3)

          ' This prints the entire report
          ' fOK = .ReportPrint(cstrReport)
        End If

        ' Close the report that's being previewed (the report doesn't need to be previewed before calling the print functions)
        .CloseObject acReport, cstrReport, acSaveNo

        ' =====================================
        ' Copying tables, modifying data, and deleting objects

        fOK = .DuplicateObject("", cstrDuplicate, acTable, "Customers")
        Debug.Print "Table duplicated " & fOK

        strSQL = "UPDATE [" & cstrDuplicate & "] SET Fax = Null"
        fOK = .ExecuteSQL(strSQL)
        Debug.Print "Update query executed " & fOK

        fOK = .OpenTable(cstrDuplicate)
        Debug.Print "Table opened " & fOK

        fOK = .CloseObject(acTable, cstrDuplicate)
        Debug.Print "Duplicate table closed " & fOK

        fOK = .DeleteObject(acTable, cstrDuplicate)
        Debug.Print "Duplicated table deleted " & fOK

        If MsgBox("Do you want to leave Access open?", vbQuestion + vbYesNo) = vbNo Then
          .CloseAccess
        End If
      End If
    End If
  End With
  Set clsAccess = Nothing

End Sub

The source code in Total Visual Sourcebook includes modules and classes for Microsoft Access, Visual Basic 6 (VB6), and Visual Basic for Applications (VBA) developers. Easily add this professionally written, tested, and documented royalty-free code into your applications to simplify your application development efforts.

Total Visual SourceBook is written for the needs of a developer using a source code library covering the many challenges you face. Countless developers over the years have told us they learned some or much of their development skills and tricks from our code. You can too!

Additional Resources

• List of All Modules in Total Visual SourceBook
• List of All Code Categories in Total Visual SourceBook
• Sample Module Code from Total Visual SourceBook (Example of Date, Time and Age Calculations)